Phrase Grammar

Program Structure

source-record:

body_opt

body:

constituents ;opt

constituents:

constituent ; …

constituent:

definition

local-declaration

expression

macro:

definition-macro-call

statement

function-macro-call

parsed-macro-call

Property Lists

comma-property-list:

, property-list

property-list:

property , …

property:

symbol value

value:

basic-fragment

Fragments

body-fragment:

non-statement-body-fragment

statement non-statement-body-fragment_opt

list-fragment:

non-statement-list-fragment

statement non-statement-list-fragment_opt

basic-fragment:

non-statement-basic-fragment

statement non-statement-basic-fragment_opt

non-statement-body-fragment:

definition semicolon-fragment_opt

local-declaration semicolon-fragment_opt

simple-fragment body-fragment_opt

, body-fragment_opt

; body-fragment_opt

semicolon-fragment:

; body-fragment_opt

non-statement-list-fragment:

simple-fragment list-fragment_opt

, list-fragment_opt

non-statement-basic-fragment:

simple-fragment basic-fragment_opt

simple-fragment:

variable-name

constant-fragment

binary-operator

unary-operator

bracketed-fragment

function-macro-call

#-word

one of . :: => ? ?? ?= ... ## otherwise

parsed-function-call

parsed-macro-call

bracketed-fragment:

( body-fragment_opt )

[ body-fragment_opt ]

{ body-fragment_opt }

constant-fragment:

number

character-literal

string

symbol

#( constants . constant )

#( constants_opt )

#[ constants_opt ]

parsed-list-constant

parsed-vector-constant

Definitions

definition:

definition-macro-call

define macro macro-definition

parsed-definition

definition-macro-call:

define modifiers_opt define-body-word body-fragment_opt definition-tail

define modifiers_opt define-list-word list-fragment_opt

modifier:

unreserved-name

modifiers:

modifier …

definition-tail:

end

end macro-name

end define-body-word macro-name

Local Declarations

local-declaration:

let bindings

let handler condition = handler

local local-methods

parsed-local-declaration

condition:

type

( type comma-property-list )

handler:

expression

local-methods:

methodopt method-definition , …

bindings:

variable = expression

( variable-list ) = expression

variable-list:

variables

variables , #rest variable-name

#rest variable-name

variables:

variable , …

variable:

variable-name

variable-name :: type

variable-name:

ordinary-name

type:

operand

Expressions

expressions:

expression , …

expression:

binary-operand binary-operator …

expression-no-symbol:

binary-operand-no-symbol

binary-operand-no-symbol binary-operator expression

binary-operand-no-symbol:

unary-operator_opt operand

binary-operand:

symbol

unary-operator_opt operand

operand:

operand ( arguments_opt )

operand [ arguments_opt ]

operand . variable-name

leaf

function-macro-call:

function-word ( body-fragment_opt )

leaf:

literal

variable-name

( expression )

function-macro-call

statement

parsed-function-call

parsed-macro-call

arguments:

argument , …

argument:

symbol expression

expression-no-symbol

symbol

literal:

number

character-literal

string-literal

#t

#f

#( constants . constant )

#( constants_opt )

#[ constants_opt ]

parsed-list-constant

parsed-vector-constant

string-literal:

string …

constants:

constant , …

constant:

literal

symbol

Statements

statement:

begin-word body-fragment_opt end-clause

end-clause:

end begin-word_opt

case-body:

cases ;opt

cases:

case-label constituents_opt ; …

case-label:

expressions =>

( expression , expressions ) =>

otherwise =>opt

Methods

method-definition:

variable-name parameter-list body_opt end methodopt variable-name_opt

parameter-list:

( parameters_opt ) ;opt

( parameters_opt ) => variable ;

( parameters_opt ) => ( values-list_opt ) ;opt

parameters:

required-parameters

required-parameters , next-rest-key-parameter-list

next-rest-key-parameter-list

next-rest-key-parameter-list:

#next variable-name

#next variable-name , rest-key-parameter-list

rest-key-parameter-list

rest-key-parameter-list:

#rest variable-name

#rest variable-name , key-parameter-list

key-parameter-list

key-parameter-list:

#key keyword-parameters_opt

#key keyword-parameters_opt , #all-keys

required-parameters:

required-parameter , …

required-parameter:

variable

variable-name == expression

keyword-parameters:

keyword-parameter , …

keyword-parameter:

symbol_opt variable default_opt

default:

= expression

values-list:

variables

variables , #rest variable

#rest variable

Macro Definitions

macro-definition:

macro-name main-rule-set aux-rule-sets_opt end macroopt macro-name_opt

main-rule-set:

body-style-definition-rule …

list-style-definition-rule …

statement-rule …

function-rule …

body-style-definition-rule:

{ define definition-head_opt macro-name pattern_opt ;opt end } => rhs

list-style-definition-rule:

{ define definition-head_opt macro-name pattern_opt } => rhs

rhs:

{ template_opt } ;opt

definition-head:

modifier-pattern …

modifier-pattern:

modifier

pattern-variable

statement-rule:

{ macro-name pattern_opt ;opt end } => rhs

function-rule:

{ macro-name ( pattern_opt ) } => rhs

Patterns

pattern:

pattern-list ; …

pattern-list:

pattern-sequence

property-list-pattern

pattern-sequence , pattern-list

pattern-sequence:

simple-pattern …

simple-pattern:

name-not-end

=>

bracketed-pattern

binding-pattern

pattern-variable

bracketed-pattern:

( pattern_opt )

[ pattern_opt ]

{ pattern_opt }

binding-pattern:

pattern-variable :: pattern-variable

pattern-variable = pattern-variable

pattern-variable :: pattern-variable = pattern-variable

pattern-variable:

? name

? constrained-name

...

property-list-pattern:

#rest pattern-variable

#key pattern-keywords_opt

#rest pattern-variable , #key pattern-keywords_opt

pattern-keywords:

#all-keys

pattern-keyword

pattern-keyword , pattern-keywords

pattern-keyword:

? name default_opt

? constrained-name default_opt

?? name default_opt

?? constrained-name default_opt

Templates

template:

template-element …

template-element:

name

symbol

number

character-literal

string

unary-operator

separator

#-word

one of . :: =>

( template_opt )

[ template_opt ]

{ template_opt }

#( template_opt )

#[ template_opt ]

parsed-list-constant

parsed-vector-constant

substitution

separator:

one of ; ,

binary-operator

substitution:

name-prefix_opt ? name-string-or-symbol name-suffix_opt

?? name separator_opt ...

...

?= name

name-prefix:

string ##

name-suffix:

## string

name-string-or-symbol:

name

string

symbol

Auxiliary Rule Sets

aux-rule-sets:

aux-rule-set …

aux-rule-set:

symbol aux-rules

aux-rules:

aux-rule …

aux-rule:

{ pattern_opt } => rhs

Parsed Fragments

parsed-definition:

(no external representation)

parsed-local-declaration:

(no external representation)

parsed-function-call:

(no external representation)

parsed-macro-call:

(no external representation)

parsed-list-constant:

(no external representation)

parsed-vector-constant:

(no external representation)